settings.gradle

pluginManagement {
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
}

plugins {
    id 'com.gradle.enterprise' version '3.15.1'
}

dependencyResolutionManagement {
    repositories {
        mavenCentral()
    }
}

gradleEnterprise {
    buildScan {
        termsOfServiceUrl = 'https://gradle.com/terms-of-service'
        termsOfServiceAgree = 'yes'
        publishAlways()
        if (System.env.CI == 'true') {
            tag 'CI'
            if (System.env.CIRCLE_TAG) {
                link 'VCS', "https://github.com/johnrengelman/shadow/tree/${System.env.CIRCLE_TAG}"
            } else {
                link 'VCS', "https://github.com/johnrengelman/shadow/tree/${System.env.CIRCLE_BRANCH}"
            }
            link 'VCS Commit', "https://github.com/johnrengelman/shadow/commit/${System.env.CIRCLE_SHA1}"
            if (System.env.CI_PULL_REQUEST) {
                link 'Pull Request', "${System.env.CI_PULL_REQUEST}"
            }
        }
    }
}

enableFeaturePreview("STABLE_CONFIGURATION_CACHE")

rootProject.name = 'shadow'