build.gradle

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    id 'java'
    id 'eclipse'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'net.minecraftforge.licenser' version '1.0.1'
    id 'net.minecraftforge.gradleutils' version '[2.3,2.4)'
}

group = 'net.minecraftforge'
version = gradleutils.tagOffsetVersion
println "Version: $version"

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
    }
    withSourcesJar()
}

repositories {
    mavenCentral()
    maven gradleutils.forgeMaven
}

dependencies {
    implementation 'net.sf.jopt-simple:jopt-simple:5.0.4'
    implementation 'net.minecraftforge:srgutils:0.4.3'
}

license {
    header = file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
}

tasks.named('jar', Jar).configure {
    manifest {
        attributes([
            'Main-Class': 'net.minecraftforge.jarsplitter.ConsoleTool',
            'Implementation-Version': project.version
        ])
    }
}

tasks.named('shadowJar', ShadowJar).configure {
    archiveClassifier = 'fatjar'
    manifest {
        attributes([
            'Main-Class': 'net.minecraftforge.jarsplitter.ConsoleTool',
            'Implementation-Version': project.version
        ])
    }
}

artifacts {
    archives shadowJar
}

publishing {
    publications.register('mavenJava', MavenPublication) {
        from components.java

        artifactId = 'jarsplitter'

        pom {
            name = 'Jar Splitter'
            description = 'Splits a jar file into classes and data, used in the Forge installer'
            url = 'https://github.com/MinecraftForge/JarSplitter'

            gradleutils.pom.setGitHubDetails(pom, 'JarSplitter')

            license gradleutils.pom.Licenses.LGPLv2_1

            developers {
                developer gradleutils.pom.Developers.LexManos
            }
        }
    }

    repositories {
        maven gradleutils.publishingForgeMaven
    }
}