From eb8192d3bb88184d55b09f465587a87e5035677d Mon Sep 17 00:00:00 2001
From: ners <ners@gmx.ch>
Date: Wed, 22 Jan 2025 21:48:51 +0100
Subject: [PATCH] console-setup: init at 1.233

---
 pkgs/by-name/co/console-setup/package.nix | 48 +++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/co/console-setup/package.nix

diff --git a/pkgs/by-name/co/console-setup/package.nix b/pkgs/by-name/co/console-setup/package.nix
new file mode 100644
index 00000000000000..c6c1fd44ae8911
--- /dev/null
+++ b/pkgs/by-name/co/console-setup/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchzip,
+  perl,
+  genericUpdater,
+  writeShellScript,
+}:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "console-setup";
+  version = "1.233";
+
+  # Git repo: https://salsa.debian.org/installer-team/console-setup.git
+  # But it seems to be offline
+  src = fetchzip {
+    url = "https://sources.debian.org/debian/pool/main/c/console-setup/console-setup_${version}.tar.xz";
+    hash = "sha256-r0QJs97cTPyOcRbMKDawfQnqFNS7wq5gJBLAg+aipDk=";
+  };
+
+  buildInputs = [ perl ];
+
+  makeFlags = [ "prefix=${placeholder "out"}" ];
+
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    patchShebangs .
+  '';
+
+  buildTargets = [ "install-linux" ];
+
+  installTargets = [ "install-linux" ];
+
+  passthru.updateScript = genericUpdater {
+    versionLister = writeShellScript "console-setup-versionLister" ''
+      curl -Ls https://sources.debian.org/api/src/console-setup/ | jq --raw-output '.versions.[] | .version'
+    '';
+  };
+
+  meta = {
+    description = "Console font and keymap setup program";
+    homepage = "https://tracker.debian.org/pkg/console-setup";
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ ners ];
+  };
+}