bintray_upload.gradle

apply plugin: 'com.github.dcendents.android-maven'
apply plugin: "com.jfrog.bintray"

group = GROUP
version = VERSION_NAME

bintray {
    user = project.hasProperty("bintray.user") ? project.getProperty("bintray.user") : "empty"
    key = project.hasProperty("bintray.apikey") ? project.getProperty("bintray.apikey") : "empty"

    configurations = ['archives'] //When uploading configuration files
    pkg {
        repo = 'android'
        userOrg = 'pixplicity'
        name = ARTIFACT_ID
        desc = POM_DESCRIPTION
        issueTrackerUrl = POM_ISSUE_URL
        vcsUrl = POM_URL
        licenses = ['Apache-2.0']
        labels = ['aar', 'android', 'font']
        publicDownloadNumbers = true
        dryRun = false //Whether to run this as dry-run, without deploying
        publish = true //If version should be auto published after an bintray_upload
    }
}

install {
    repositories.mavenInstaller {
        pom {
            project {
                packaging 'aar'
                name project.name
                url POM_URL
                description POM_DESCRIPTION
                licenses {
                    license {
                        name POM_LICENCE_NAME
                        url POM_LICENCE_URL
                        distribution POM_LICENCE_DIST
                    }
                }
                developers {
                    developer {
                        id POM_DEVELOPER_ID_0
                        name POM_DEVELOPER_NAME_0
                        email POM_DEVELOPER_EMAIL_0
                    }
                    developer {
                        id POM_DEVELOPER_ID_1
                        name POM_DEVELOPER_NAME_1
                        email POM_DEVELOPER_EMAIL_1
                    }
                }
                scm {
                    connection POM_SCM_CONNECTION
                    developerConnection POM_SCM_DEV_CONNECTION
                    url POM_URL

                }
            }
        }
    }
}

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

task findConventions << {
    println project.getConvention()
}