build.gradle

plugins {
    id "idea"
    id "jacoco"
    id "maven-publish"
    id "org.jetbrains.kotlin.jvm" version "1.9.22"
    id "org.jlleitschuh.gradle.ktlint" version "12.1.1"
}

ext {
    kotlinVersion = "1.9.22"
    playwrightVersion = "1.46.0"
    junitVersion = "5.11.0"
    assertjVersion = "3.26.3"
    slf4jVersion = "2.0.16"
    logbackVersion = "1.5.8"
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

ktlint {
    version.set("1.1.1")
}

repositories {
    mavenCentral()
}

[compileKotlin, compileTestKotlin]*.kotlinOptions*.jvmTarget = "17"

dependencies {
    api "com.microsoft.playwright:playwright:$playwrightVersion"
    api "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"
    api "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"

    testImplementation "org.slf4j:slf4j-api:$slf4jVersion"
    testImplementation "ch.qos.logback:logback-classic:$logbackVersion"

    testImplementation "org.assertj:assertj-core:$assertjVersion"
    testImplementation "org.junit.jupiter:junit-jupiter:$junitVersion"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitVersion"
}

test {
    useJUnitPlatform()
    testLogging {
        showStandardStreams = true
    }
}

jacocoTestReport {
    reports {
        xml.required = true
        html.required = false
    }
}

check.dependsOn jacocoTestReport

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
            pom {
                name = "playwright-page-object"
                description = "Page Object pattern for Playwright framework"
                licenses {
                    license {
                        name = "The MIT License"
                        url = "https://opensource.org/license/mit"
                    }
                }
                developers {
                    developer {
                        name = "Romanov Alex"
                        email = "romanowalex@mail.ru"
                    }
                }
                scm {
                    url = "https://github.com/Romanow/playwright-page-object/"
                }
            }
        }
    }
    repositories {
        maven {
            url = uri("https://maven.pkg.github.com/Romanow/playwright-page-object")
            credentials {
                username = System.getenv("GITHUB_USER")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}