Downlink pointer issues

[ChaiFox]

I'll start by saying I rarely do stuff in C++, I have the heltec wireless tracker and have gotten everything working except the downlinks. Specifically when using the methods that use a pointer for downlink length. The data comes through fine and it works great as long as the data is 4 bytes or less, once its over 4 bytes though the size stored by the length pointer RAPIDLY balloons and it becomes unusable.

10:59:30.655 > [Radio] Initializing ... success!
10:59:30.707 > [LoRaWAN] Attempting over-the-air activation ... success!
10:59:35.160 > no downlink!
11:00:36.355 > received a downlink!
11:00:36.355 > TEST
11:00:36.355 > pointer:  4, strlen:  5 
11:00:36.355 > [LoRaWAN] RSSI:          -13.00 dBm
11:00:36.355 > [LoRaWAN] SNR:           10.25 dB
11:00:36.356 > [LoRaWAN] Frequency error:       31.00 Hz
11:01:37.602 > received a downlink!
11:01:37.603 > TESTE
11:01:37.603 > pointer:  69, strlen:  5 
11:01:37.603 > [LoRaWAN] RSSI:          -15.00 dBm
11:01:37.603 > [LoRaWAN] SNR:           9.75 dB
11:01:37.603 > [LoRaWAN] Frequency error:       31.00 Hz

#include <RadioLib.h>
#include <CayenneLPP.h>
#include <CayenneLPPDec.h>

//-----LORAWAN-----
#define RADIO_DIO_1  14
#define RADIO_NSS    8
#define RADIO_RESET  12
#define RADIO_BUSY   13
#define LORA_CLK     9
#define LORA_MISO    11
#define LORA_MOSI    10

//used for downlink
size_t len;      size_t* lenPtr = &len;
uint8_t buff;  uint8_t* buffPtr = &buff;

SPIClass radio_spi(FSPI);
SPISettings spiSettings(2000000, MSBFIRST, SPI_MODE0);
SX1262 radio = new Module(RADIO_NSS, RADIO_DIO_1, RADIO_RESET, RADIO_BUSY, radio_spi, spiSettings);

LoRaWANNode node(&radio, &US915, 1);

void downLinkDataHandle(uint8_t* dataIn, size_t* dataSize, JsonArray array){

  
}

static void prepareTxFrame() {

}

void setup() {
  Serial.begin(115200);
  delay(5000);	// small delay to allow serial console to connect

  pinMode(RADIO_NSS, OUTPUT);
  radio_spi.begin(LORA_CLK, LORA_MISO, LORA_MOSI, RADIO_NSS);
  
  // initialize radio (SX1262 / SX1278 / ... ) with default settings
  Serial.print(F("[Radio] Initializing ... "));
  int state = radio.begin();
  if(state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while(true);
  }

uint64_t joinEUI = 0x12AD1011B0C0FFEE;
uint64_t devEUI = 0x2232330000888805;

// network key is the ASCII string "topSecretKey1234"
uint8_t nwkKey[] = { 0x74, 0x6F, 0x70, 0x53, 0x65, 0x63, 0x72, 0x65,
                      0x74, 0x4B, 0x65, 0x79, 0x31, 0x32, 0x33, 0x34 };

// application key is the ASCII string "aDifferentKeyABC"
uint8_t appKey[] = { 0x88, 0x88, 0x88, 0x88, 0x88, 0x88, 0x88, 0x88,
                      0x88, 0x88, 0x88, 0x88, 0x88, 0x88, 0x66, 0x01 };

  Serial.print(F("[LoRaWAN] Attempting over-the-air activation ... "));
  state = node.beginOTAA(joinEUI, devEUI, nwkKey, appKey);

  if(state >= RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
    delay(2000);	// small delay between joining and uplink
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while(true);
  }


}

int count = 0;

void loop() {

  String strUp = "Hello!" + String(count++);
  String strDown;

  int state = node.sendReceive(strUp.c_str(), 1, buffPtr, lenPtr);

  if(state == RADIOLIB_ERR_NONE) {
    Serial.println(F("received a downlink!"));

    strDown = String((char* )buffPtr);
    if(strDown.length() > 0) {
      Serial.println(strDown);
    Serial.printf("pointer: % i, strlen: % i \n",*lenPtr,strDown.length());

    } else {
      Serial.println(F("<MAC commands only>"));
    }

    // print RSSI (Received Signal Strength Indicator)
    Serial.print(F("[LoRaWAN] RSSI:\t\t"));
    Serial.print(radio.getRSSI());
    Serial.println(F(" dBm"));

    // print SNR (Signal-to-Noise Ratio)
    Serial.print(F("[LoRaWAN] SNR:\t\t"));
    Serial.print(radio.getSNR());
    Serial.println(F(" dB"));

    // print frequency error
    Serial.print(F("[LoRaWAN] Frequency error:\t"));
    Serial.print(radio.getFrequencyError());
    Serial.println(F(" Hz"));
  
  } else if(state == RADIOLIB_ERR_RX_TIMEOUT) {
    Serial.println(F("no downlink!"));
  
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
  }

  node.saveSession();
  
  // wait before sending another packet
  uint32_t minimumDelay = 60000;                  // try to send once every minute
  uint32_t interval = node.timeUntilUplink();     // calculate minimum duty cycle delay (per law!)
  uint32_t delayMs = max(interval, minimumDelay); // cannot send faster than duty cycle allows

  delay(delayMs);
}

I'm really not sure whats going on as if I use the sendRecieve method that uses Strings it works fine with Strings of any length, unfortunately the data will be using LPP so that is not an option for me. Any help in figuring out what the heck is going on would be appreciated

[jgromes]

The number 69 is a rather interesting value - have you noticed that in ASCII, it translates to E, whcih just so happens to be the second letter of "TEST" or the fifth letter of "TESTE"?

uint8_t buff;  uint8_t* buffPtr = &buff;

buff here is not a buffer, it's a variable which is 1 byte in size. If you try to get its address, you will get a pointer to the variable. You can store exactly 1 byte of data here. If you store more, you will start to write stuff in memory imediately after the buff. Without running the code, my guess is your "TEST" or "TESTE" string overwrites the length value.

You will need to use an actual buffer here. For example, if you know that your data will always be less thank 100 bytes in length, you can just do the following:

uint8_t buff[100];  uint8_t* buffPtr = &buff[0];

But I will warn you that you seem to be missing some C/C++ fundamentals which will inevitably come back to haunt you. I would suggest taking a while to learn about arrays and pointers before trying to build m,ore advanced stuff - and LoRaWAN certainly falls into that category.

[HeadBoffin]

This may help as a starting point: https://www.thethingsnetwork.org/docs/devices/bytes/

As I'm working on updating the examples, I'll quickly test the part 2 that shows downlinks and post it here shortly (next 24 hours) - to get you started there is WIP that does a send using a byte array here: https://github.com/HeadBoffin/RadioLib_DevCopy/blob/master/examples/LoRaWAN/Starter/Starter.ino

[ChaiFox]

Thank you both! Now that you pointed it out I can see what I was doing wrong and now after the changes its no longer behaving incorrectly.
After not doing any software work for 15yrs, and having not worked with C then either, I guess I do need to just byte (lol) the bullet and pause the project while I learn to work with C.