Physical Payload

[tanguy-e]

Hello, i use the radiolib to send data to TTN. I would like to write the physical payload that is sent in the serial monitor.
How can i do this ?
Thanks
Eric

[HeadBoffin]

Bit hard to answer without knowing what your code looks like but the latest examples have a call for that as it's a common requirement:

RadioLib/examples/LoRaWAN/LoRaWAN_Starter/config.h

Line 122 in 7b52111

void arrayDump(uint8_t *buffer, uint16_t len) {

For the examples you'd call it like arrayDump(uplinkPayload, sizeof(uplinkPayload));

[tanguy-e]

I'm not sure to understand the answer. In this code, i write the data payload but i would like to write also the physical paylaod :

#include <RadioLib.h>                 // Inclusion de la bibliothèque RadioLib pour la communication radio
#include <Wire.h>                     // Inclusion de la bibliothèque Wire pour la communication I2C
#include <Adafruit_BMP280.h>          // Inclusion de la bibliothèque Adafruit_BMP280 pour le capteur de pression et de température
#include <CayenneLPP.h>               // Inclusion de la bibliothèque CayenneLPP pour le formatage des données pour LoRaWAN

SX1262 radio = new Module(8, 14, 12, 13);   // Création d'une instance de module LoRa avec les broches spécifiées

LoRaWANNode node(&radio, &EU868);            // Création d'une instance de nœud LoRaWAN avec le module radio et la bande de fréquence spécifiée

Adafruit_BMP280 bmp;                         // Création d'une instance de capteur BMP280
CayenneLPP lpp(51);                          // Création d'une instance de CayenneLPP avec une taille maximale de 51 octets

void setup() {
  Serial.begin(112500);                      // Initialisation de la communication série à 112500 bauds
  
  unsigned status;                            // Déclaration d'une variable pour le statut
  status = bmp.begin(BMP280_ADDRESS_ALT, BMP280_CHIPID);   // Initialisation du capteur BMP280 avec l'adresse et l'ID spécifiés
  if (!status) {
    Serial.println(F("Could not find a valid BMP280 sensor, check wiring or "
                     "try a different address!"));   // Message d'erreur si le capteur BMP280 n'est pas trouvé
  }
  bmp.setSampling(Adafruit_BMP280::MODE_NORMAL,     
                  Adafruit_BMP280::SAMPLING_X2,     
                  Adafruit_BMP280::SAMPLING_X16,    
                  Adafruit_BMP280::FILTER_X16,      
                  Adafruit_BMP280::STANDBY_MS_500);   // Configuration de l'échantillonnage du capteur BMP280

  int state = radio.begin();                  // Initialisation du module LoRa
  if(state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));            // Message de réussite de l'initialisation
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while(true);
  }
    
  uint64_t joinEUI = 0x0000000000000000;     // Identifiant d'application pour la connexion OTAA
  uint64_t devEUI = 0x70B3D57ED006522D;       // Identifiant de périphérique pour la connexion OTAA

  uint8_t nwkKey[] = { 0x95, 0xAC, 0x48, 0x4C, 0x0B, 0x6C, 0xA1, 0x99, 0xF8, 0x03, 0x11, 0xCA, 0xDA, 0xA7, 0x74, 0xC1 };   // Clé de réseau pour la connexion OTAA
  uint8_t appKey[] = { 0xF5, 0xD8, 0x93, 0x27, 0x8F, 0x7E, 0x3F, 0x23, 0xC3, 0xDA, 0xB5, 0xA1, 0x9A, 0xE0, 0xCD, 0x6C };   // Clé d'application pour la connexion OTAA

  Serial.print(F("[LoRaWAN] Tentative de connexion OTAA ... "));
  state = node.beginOTAA(joinEUI, devEUI, nwkKey, appKey);   // Connexion au réseau LoRaWAN via la méthode OTAA

  if(state >= RADIOLIB_ERR_NONE) {
    Serial.println(F("Connexion!"));          // Message de réussite de la connexion
    delay(2000);                              // Petit délai entre la connexion et l'envoi de données
  } else {
    Serial.print(F("Echoué, code "));
    Serial.println(state);
    while(true);
  }
}

void loop() {
  char str[30];                               // Déclaration d'un tableau de caractères pour stocker des chaînes de caractères
  float temperature = bmp.readTemperature();   // Lecture de la température à partir du capteur BMP280
  float pressure = (bmp.readPressure()/100.0); // Lecture de la pression atmosphérique à partir du capteur BMP280 et conversion en hPa

  sprintf(str,"Température : %.1f °C",temperature);   // Formatage de la température dans une chaîne de caractères
  Serial.println();
  Serial.println(str);                                 // Affichage de la température sur le moniteur série
  sprintf(str,"Pression : %.1f hPa",pressure);        // Formatage de la pression dans une chaîne de caractères
  Serial.println(str);                                 // Affichage de la pression sur le moniteur série
  
  lpp.reset();                                          // Réinitialisation de l'objet CayenneLPP

  lpp.addTemperature(1, temperature);                  // Ajout de la température au paquet CayenneLPP sur le canal 1
  lpp.addBarometricPressure(2, pressure);              // Ajout de la pression au paquet CayenneLPP sur le canal 2

  byte packet[lpp.getSize()];                          // Déclaration d'un tableau d'octets pour stocker le paquet CayenneLPP
  lpp.copy(packet);                                    // Copie du paquet CayenneLPP dans le tableau d'octets

  Serial.print("Octets envoyés : ");
  Serial.println(lpp.getSize());                       // Affichage du nombre d'octets envoyés

  Serial.print("Trame envoyée : ");
  uint8_t *payload = lpp.getBuffer();

  for (unsigned char i = 0; i < lpp.getSize(); i++)   // Boucle pour afficher chaque octet de la trame envoyée en format hexadécimal
  {
    Serial.print("0x");
    Serial.print(payload[i], HEX);
    Serial.print(" ");
  }
  Serial.println();

  Serial.println(F("[LoRaWAN] En train d'envoyer la trame ... "));
  int state = node.uplink(lpp.getBuffer(), lpp.getSize(), 10);   // Envoi du paquet CayenneLPP en tant que transmission ascendante
    String strDown;  // Déclaration d'une variable pour stocker les données de la réception descendante

  if(state != RADIOLIB_ERR_NONE) {
    Serial.println(F("Erreur d'envoi!"));  // Message d'erreur en cas d'échec de l'envoi
  }

  state = node.downlink(strDown);  // Réception des données descendantes

  if(state == RADIOLIB_ERR_NONE) {
    Serial.println(F("Réception reçue!"));  // Message de réussite de la réception

    Serial.println(F("[LoRaWAN] Data:\t\t"));
    if(strDown.length() > 0) {
      Serial.print("Message reçu : ");
      Serial.println(strDown);  // Affichage des données de la réception si elles existent
    } else {
      Serial.println(F("<MAC commands only>"));  // Affichage si seules des commandes MAC sont reçues
      Serial.println(strDown);
    }

    Serial.print(F("[LoRaWAN] RSSI:\t\t"));
    Serial.print(radio.getRSSI());  // Affichage de la force du signal RSSI

    Serial.println(F(" dBm"));

    Serial.print(F("[LoRaWAN] SNR:\t\t"));
    Serial.print(radio.getSNR());   // Affichage du rapport signal sur bruit SNR
    Serial.println(F(" dB"));

    Serial.print(F("[LoRaWAN] Frequency error:\t"));
    Serial.print(radio.getFrequencyError());  // Affichage de l'erreur de fréquence
    Serial.println(F(" Hz"));

  } else if(state == RADIOLIB_ERR_RX_TIMEOUT) {
    Serial.println(F("Pas de réception!"));  // Message si aucune réception n'est reçue

  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
  }

  node.saveSession();  // Sauvegarde de la session LoRaWAN
  
  uint32_t minimumDelay = 60000;                  // Temps minimal entre l'envoi de chaque paquet (60 secondes)
  uint32_t interval = node.timeUntilUplink();     // Calcul du temps écoulé depuis la dernière transmission
  uint32_t delayMs = max(interval, minimumDelay); // Calcul du temps d'attente en fonction du délai minimal et du temps écoulé

  delay(delayMs);  // Attente avant d'envoyer un autre paquet
}

[HeadBoffin]

I can cope with the language but not the formatting - please edit to format your code with the code tags in the toolbar.

[tanguy-e]

Better ?

[StevenCellist]

If you wish to see the complete package that is sent, you can enable RADIOLIB_DEBUG_PROTOCOL in BuildOptUser.h or from platformio.ini. There is no method available to get the complete physical payload.

[tanguy-e]

Thank you very much. In the last version available in Arduino IDE, i have only this in BuildOptUser.h :

#if !defined(_RADIOLIB_USER_BUILD_OPTIONS_H)
#define _RADIOLIB_USER_BUILD_OPTIONS_H

// this file can be used to define any user build options
// most commonly, RADIOLIB_EXCLUDE_* macros
// or enabling debug output

//#define RADIOLIB_DEBUG    (1)
//#define RADIOLIB_VERBOSE  (1)

#endif

[StevenCellist]

Ah, the normal DEBUG flag then. The one I mentioned is upcoming in 6.5.0.

[tanguy-e]

Thanks. I will give it a try.
What is the default LoRaWAN version used (1.04, 1.1) ?

[tanguy-e]

Ok sorry. I should have looked first... The default version is 1.1 but is there a possibility of forcing it to be 1.0.4?

[StevenCellist]

Not really, because it is not supported and likely to be not fully compliant.

[HeadBoffin]

Why do you want to use 1.0.4?

[tanguy-e]

I use Radiolib to send LoRA - LoRaWAN datas to TTN. The frame are well decoded in the end device part of TTN. But i would like to better understand the LoRaWAN coding frame. So i take the frame received in TTN and try to decode it using LoRaWAN packet decoder : https://lorawan-packet-decoder-0ta6puiniaut.runkit.sh/?data=QPjyCyaAhAEKxgot72bu6AZmyLrY&nwkskey=95AC484C0B6CA199F80311CADAA774C1&appskey=F5D893278F7E3F23C3DAB5A19AE0CD6C
And it found there is a problem decoding MIC.
So thinking the problem come from the LoRaWAN version (it seems that there is a big difference between 1.0.x and 1.1 for coding/decoding MIC) i would like to test with a 1.0.x frame.

[StevenCellist]

I can guarantee you that the LoRaWAN packet decoder works for 1.0.x (used it very often), but it indeed is not able to verify the MIC of 1.1 packets. This is because LoRaWAN v1.1 uses two additional keys: the FNwkSIntKey (Forwarding integrity key) and the SNwkSIntKey (Serving integrity key). As you found out, the packet decoder has no options for these two fields.
If you want to know the MIC calculation: it's all in the spec chapter 4.4.2. Beyond that spec, I don't see any reason to dig into this any further.

[HeadBoffin]

Whilst you can get the full payload with DEBUG turned on, along with a whole pile of other information, looking at the physical payload that is mostly encrypted is somewhat academic and has so many levels of detail that you'll need to have read the LW spec a few times to make much sense of it. The rest of the LW debug output also requires a reasonably complete understanding of the LW spec. Even @StevenCellist missed a trick today on the TTS repro and he's been living & breathing the spec since early November.

[HeadBoffin]

@tanguy-e, you may have missed this - RadioLib LW targets 1.1, the over-the-air payload can be extracted from either the debug log or if it's missing, you can put some additional output in to LoRaWAN.cpp which technically will be quite trivial compared to decoding by hand!

As such I too can't see what other input can be provided at this time - maybe we will have capacity to create some materials to guide people, but for now the only real option is to just read the specs, which is what we did. You will find people on the TTN forum that know far more about the details but again, they are likely to be time poor as well.

Good luck!