How to pass polymorphic effect type into another effect signature?

[chtenb]

pub effect iter<a>
  ctl yield(elem : a) : ()

pub fun foreach(it : () -> <iter<a>,div> (), do : a -> e ()) : <div|e> ()
  with ctl yield(elem)
    do(elem)
    resume(())
  it()

The idea is that <iter<a>,div> represents a potentially infinite lazy iterator.
This foreach function however, gives an error of

  error: effects do not match
  context        :   with ctl yield(elem)
                   ...
                     it()
  term           :   it()
  inferred effect: <div,iter<$a>|_e1>
  expected effect: <iter<$a>|$e>

If I remove the e effect from do, it compiles fine. How would you pass the e on to the outer signature of foreach?

I could add the effect to it as well, which changes the error message slightly, but still doesn't compile:

error: effects do not match
  context        :   with ctl yield(elem)
                   ...
                     it()
  term           :   it()
  inferred effect: <div,iter<$a>|$e>
  expected effect: <iter<$a>|$e>

[TimWhiting]

If one function needs divergence, every function that runs in the same scope essentially has to at least have divergence.
So the solution is to add divergence to both input parameters.

Divergence inference is still pretty immature compared to the rest of the type system. Granted, it is trying to solve a small portion of the halting problem, so it's not going to be perfect.

pub effect iter<a>
  ctl yield(elem : a) : ()

pub fun foreach(it : () -> <iter<a>,div> (), do : a -> <div|e> ()) : <div|e> ()
  with ctl yield(elem)
    do(elem)
    resume(())
  it()

[chtenb]

Yeah, I read the paper discussing the termination checker recently. That part has become more clear to me now. I still don't always understand how the effect inference works. Usually making the effects of parameters the same to the function being defined helps. Like your suggestion in fact. Alternatively, since this function doesn't really need divergence at all I you can also leave it out like this

pub effect iter<a>
  ctl yield(elem : a) : ()

pub fun foreach(it : () -> <iter<a>|e> (), do : a -> e ()) : e ()
  with ctl yield(elem)
    do(elem)
    resume(())
  it()

This also compiles