build.gradle

plugins {
  id "java"
  id "edu.wpi.first.GradleRIO" version "2025.1.1"
  id "com.peterabeles.gversion" version "1.10"
}

java {
  sourceCompatibility = JavaVersion.VERSION_17
  targetCompatibility = JavaVersion.VERSION_17
}

def ROBOT_MAIN_CLASS = "frc.robot.Main"

repositories {
  maven {
    url = "https://maven.pkg.github.com/Mechanical-Advantage/AdvantageKit"
    credentials {
      username = "Mechanical-Advantage-Bot"
      password = "\u0067\u0068\u0070\u005f\u006e\u0056\u0051\u006a\u0055\u004f\u004c\u0061\u0079\u0066\u006e\u0078\u006e\u0037\u0051\u0049\u0054\u0042\u0032\u004c\u004a\u006d\u0055\u0070\u0073\u0031\u006d\u0037\u004c\u005a\u0030\u0076\u0062\u0070\u0063\u0051"
    }
  }

  maven { url = "https://jitpack.io" }
}

configurations.all {
  exclude group: "edu.wpi.first.wpilibj"
}

project.compileJava.dependsOn(createVersionFile)
gversion {
  srcDir       = "src/main/java/"
  classPackage = "frc.robot"
  className    = "BuildConstants"
  dateFormat   = "yyyy-MM-dd HH:mm:ss z"
  timeZone     = "America/Chicago" // Use preferred time zone
  indent       = "  "
}

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
  targets {
    roborio(getTargetTypeClass('RoboRIO')) {
      // Team number is loaded either from the .wpilib/wpilib_preferences.json
      // or from command line. If not found an exception will be thrown.
      // You can use getTeamOrDefault(team) instead of getTeamNumber if you
      // want to store a team number in this file.
      team = project.frc.getTeamNumber()
      debug = project.frc.getDebugOrDefault(false)

      artifacts {
        // First part is artifact name, 2nd is artifact type
        // getTargetTypeClass is a shortcut to get the class type using a string

        frcJava(getArtifactTypeClass('FRCJavaArtifact')) {
        }

        // Static files artifact
        frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
            files = project.fileTree('src/main/deploy')
            directory = '/home/lvuser/deploy'
            deleteOldFiles = true // Change to true to delete files on roboRIO that no
                                  // longer exist in deploy directory of this project
        }
      }
    }
  }
}

def deployArtifact = deploy.targets.roborio.artifacts.frcJava

// Set to true to use debug for JNI.
wpi.java.debugJni = false

// Set this to true to enable desktop support.
def includeDesktopSupport = true

// Get AdvantageKit version from vendordep file
def AdvantageKitJSON = new groovy.json.JsonSlurper().parseText(new File(projectDir.getAbsolutePath() + "/vendordeps/AdvantageKit.json").text)

// Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
// Also defines JUnit 5.
dependencies {
  annotationProcessor wpi.java.deps.wpilibAnnotations()
  implementation wpi.java.deps.wpilib()
  implementation wpi.java.vendor.java()

  roborioDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.roborio)
  roborioDebug wpi.java.vendor.jniDebug(wpi.platforms.roborio)

  roborioRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.roborio)
  roborioRelease wpi.java.vendor.jniRelease(wpi.platforms.roborio)

  nativeDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.desktop)
  nativeDebug wpi.java.vendor.jniDebug(wpi.platforms.desktop)
  simulationDebug wpi.sim.enableDebug()

  nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.desktop)
  nativeRelease wpi.java.vendor.jniRelease(wpi.platforms.desktop)
  simulationRelease wpi.sim.enableRelease()

  //implementation fileTree(dir: 'libs', include: '*.jar')
  implementation 'com.github.lasarobotics:PurpleLib:2025.0.1'

  implementation 'org.apache.commons:commons-math3:3.+'
  implementation 'org.tinylog:tinylog-api:2.7.0'
  implementation 'org.tinylog:tinylog-impl:2.7.0'

  testImplementation 'org.junit.jupiter:junit-jupiter:5.+'
  testImplementation 'org.mockito:mockito-core:3.+'

  testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.+'

  annotationProcessor "org.littletonrobotics.akit:akit-autolog:$AdvantageKitJSON.version"
}

test {
  useJUnitPlatform()
  systemProperty 'junit.jupiter.extensions.autodetection.enabled', 'true'
}

// Simulation configuration (e.g. environment variables).
wpi.sim.addGui().defaultEnabled = true
wpi.sim.addDriverstation()

// Setting up my Jar File. In this case, adding all libraries into the main jar ('fat jar')
// in order to make them all available at runtime. Also adding the manifest so WPILib
// knows where to look for our Robot Class.
jar {
  from { configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) } }
  from sourceSets.main.allSource
  manifest edu.wpi.first.gradlerio.GradleRIOPlugin.javaManifest(ROBOT_MAIN_CLASS)
  duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

// Configure replay watch task
task(replayWatch, type: JavaExec) {
  mainClass = "org.littletonrobotics.junction.ReplayWatch"
  classpath = sourceSets.main.runtimeClasspath
}

// Configure jar and deploy tasks
deployArtifact.jarTask = jar
wpi.java.configureExecutableTasks(jar)
wpi.java.configureTestTasks(test)

// Configure string concat to always inline compile
tasks.withType(JavaCompile) {
  options.compilerArgs.add '-XDstringConcat=inline'
}