build.gradle

buildscript {
	repositories {
		jcenter()
	}
	dependencies {
		classpath 'com.github.townsfolk:gradle-release:1.2'
		classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
	}
}


apply plugin: 'release'
apply plugin: "com.bancvue.core-oss"
apply plugin: "com.bancvue.integration-test"
apply plugin: "com.bancvue.maven-publish-ext"
apply plugin: 'com.jfrog.bintray'

repositories {
	jcenter()
}

dependencies {
	compile localGroovy()
	compile gradleApi()
	compile "nl.javadude.gradle.plugins:license-gradle-plugin:0.11.0"

	mainTestCompile('org.spockframework:spock-core:1.0-groovy-2.4') {
		exclude group: 'org.codehaus.groovy'
	}
	mainTestCompile 'cglib:cglib-nodep:3.2.2'
	mainTestCompile 'org.objenesis:objenesis:2.2'
}

check.dependsOn integrationTest

license {
	ext.name = "BancVue, LTD"
	skipExistingHeaders true
}

[licenseMain, licenseFormatMain]*.exclude "licenses/*"
// exclude the test kit source which was copied from a different project (https://github.com/alkemist/gradle-test-kit)
// and has it's own license
[licenseMainTest, licenseFormatMainTest]*.exclude "org/gradle/testkit/**"


publishing_ext {
	publication("mainTest")

	publishJavadoc true
	pom {
		packaging "jar"
		description "A collection of gradle plugins meant to codify and streamline project development."
		url "https://github.com/BancVue/gradle-core"
		developers {
			developer {
				id "bancvue_oss"
				name "BancVue Open Source Development"
				email "opensource@bancvue.com"
			}
		}
		scm {
			url "https://github.com/BancVue/gradle-core.git"
			connection "scm:git:git@github.com:BancVue/gradle-core.git"
			developerConnection "scm:git:git@github.com:BancVue/gradle-core.git"
		}
	}
}

bintray {
	user = 'bancvue'
	key = '-changeme-'

	publications = ['gradleCore', 'gradleCoreTest']
	dryRun = false
	publish = false
	pkg {
		repo = 'maven'
		userOrg = 'bancvue'
		name = project.group + ':' + project.ext['artifactId']
		desc = project.description
		websiteUrl = 'https://github.com/BancVue/gradle-core'
		issueTrackerUrl = 'https://github.com/BancVue/gradle-core/issues'
		vcsUrl = 'https://github.com/BancVue/gradle-core.git'
		licenses = ['Apache-2.0']
		labels = ['gradle']
		publicDownloadNumbers = true
		version {
			vcsTag = project.version
			attributes = ['gradle-plugin': 'com.bancvue.core-oss:com.bancvue:gradle-core']
		}
	}
}