-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathm2sm.mod
1431 lines (1268 loc) · 37.1 KB
/
m2sm.mod
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*$Segment M2SM*)
(*$RangeCheck+*)
(*$OverflowCheck+*)
IMPLEMENTATION MODULE M2SM; (* NW 17.8.83 / 23.3.85; HS 31.5.86 / 28.4.89 *)
FROM ASCII IMPORT nul, cr, bs;
FROM ConsoleIO IMPORT scEnableMouse, scDisableMouse, scSetNormal,
scSetInverse;
FROM EZFileSystem IMPORT MakeFileName;
FROM FastFileSystem IMPORT
Load, ReadChar, GetPos, SetPos, Purge, Response;
FROM GSOSInterface IMPORT GSOSOutString, GSOSNameString, getNameDCB,
GetName, AccessSet, aaReadEnabled, StringToGSOSOutString;
FROM InOut IMPORT WriteString, Write, WriteLn, WriteCard, WriteHex,
WriteLongInt;
FROM MemoryManager IMPORT Handle;
FROM M2Debug IMPORT lineType, step, breakPoint, autoGo, breakPointCode,
autoGoCode;
FROM M2DM IMPORT MaxCard, rngchk, ovflchk, stackchk, ObjPtr, nilchk, databank;
FROM M2HM IMPORT errorInProc, curLev;
FROM M2Lib IMPORT ToolError;
FROM M2LM IMPORT segmentName, IdToSymbol, CDAName, CDAShutdown, NDAOpen,
NDAClose, NDAAction, NDAPeriod, NDAMask, NDAMenuline, Stacksize,
aSymbol, KeepName, ChainToName, CDEVName;
FROM M2Shell IMPORT ShowProgress, userHasAborted, objectFileInError,
outFileMask, keepStyle, KeepObject, AllErrFatal, terminalError,
OutputFile, ListSource, PauseOnError;
FROM NumberConversion IMPORT CardToString;
FROM OrcaShell IMPORT StopDCB, Stop, aKeepStyle, ConsoleOutDCB, ConsoleOut;
FROM ResourceManager IMPORT LoadResource, GetCurResourceFile, sysFileID,
CloseResourceFile, OpenResourceFile;
FROM Storage IMPORT ALLOCATE, DEALLOCATE;
FROM Strings IMPORT Assign, Concat, Length, Insert;
FROM Terminal IMPORT BusyRead, Read;
FROM SYSTEM IMPORT ADR, ADDRESS;
CONST
KW = 44; (* number of keywords *)
maxDig = 15; (* to avoid floating overflow in scanner *)
maxExp = 308; (* note the correspondence with the pow-array! *)
maxBuf = 30; (* maximum length for a number *)
IdBufLim = IdBufLeng - 100;
maxDirective = 17;
eol = cr;
TYPE
l2w =
RECORD
CASE :BOOLEAN OF
TRUE: long: LONGINT;
| FALSE: p1,p0: CARDINAL;
END;
END;
aSymbolPos =
RECORD
pos: l2w;
line: l2w;
lineNum: CARDINAL;
colNum: CARDINAL;
END;
VAR
ch: CHAR; (* current character *)
id0: CARDINAL;
id1: CARDINAL; (* indices of identifier buffer *)
pow: ARRAY [0..8] OF LONGREAL; (* must cover exponent range *)
keyTab: ARRAY [0..KW-1] OF
RECORD
sym: Symbol;
ind: CARDINAL;
END;
D: CARDINAL;
K: CARDINAL;
lastLine: l2w;
prevSym: aSymbolPos;
lastSym: aSymbolPos;
sourceColumn: CARDINAL;
eolDet: BOOLEAN;
dirTab: ARRAY [0..maxDirective-1] OF
RECORD
directive: aDirective;
name: CARDINAL;
END;
errorStringHandle: Handle;
errorString: POINTER TO ARRAY [0..79] OF CHAR;
unknownError:
RECORD
CASE :BOOLEAN OF
TRUE: message: ARRAY [0..55] OF CHAR;
| FALSE: text: ARRAY [0..16] OF CHAR; (* "Unknown error. (#" *)
number: ARRAY [0..2] OF CHAR;
text2: ARRAY [0..34] OF CHAR; (* ") Please contact customer support." *)
END;
END;
myResourceFile: CARDINAL;
PROCEDURE ClearModList;
VAR
ce, ne: pModListEntry;
BEGIN
ce := modList;
WHILE ce <> NIL DO
ne := ce;
ce := ce^.next;
DEALLOCATE(ne, SIZE(aModListEntry));
END;
modList := NIL;
END ClearModList;
PROCEDURE DisplayLastLine;
VAR
buf: CHAR;
curr: l2w;
BEGIN
IF ShowProgress THEN
GetPos(source, curr.long);
SetPos(source, lastLine.long);
ReadChar(source, buf);
WHILE (buf <> eol) AND (NOT source.eof) DO
Write(buf);
ReadChar(source, buf);
END;
WriteLn;
SetPos(source, curr.long);
END;
END DisplayLastLine;
PROCEDURE GetCh;
BEGIN
ReadChar(source, ch);
IF source.res = done THEN
IF ch = eol THEN
IF eolDet THEN
INC(sourceLine);
sourceColumn := 1;
GetPos(source, lastLine.long);
IF ListSource AND ShowProgress THEN
WriteLn;
END;
ELSIF ListSource THEN
DisplayLastLine;
END;
eolDet := TRUE;
ELSIF ch >= ' ' THEN
IF eolDet THEN
INC(sourceLine);
sourceColumn := 1;
GetPos(source, lastLine.long);
DEC(lastLine.long);
eolDet := FALSE;
lineType := step;
ELSE
INC(sourceColumn);
END;
END;
IF ch = breakPointCode THEN
lineType := breakPoint;
GetCh;
ELSIF ch = autoGoCode THEN
lineType := autoGo;
GetCh;
END;
END; (* if ReadChar done *)
END GetCh;
PROCEDURE MarkSym;
BEGIN
prevSym := lastSym;
WITH lastSym DO
GetPos(source, pos.long);
DEC(pos.long);
line := lastLine;
lineNum := sourceLine;
colNum := sourceColumn;
END;
END MarkSym;
PROCEDURE Mark(n: CARDINAL);
PROCEDURE LoadError(error: CARDINAL);
CONST
errorOffset = 2000H;
rCString = 801DH;
BEGIN
IF (error < 400) OR (error > 499) THEN
errorStringHandle := LoadResource(rCString, error+errorOffset);
IF (errorStringHandle = NIL) OR
(ToolError() <> 0) THEN
errorString := ADR(unknownError.message);
CardToString(error, unknownError.number, 3);
ELSE
errorString := errorStringHandle^;
END;
ELSE
errorString := ADR(unknownError.message);
CardToString(error, unknownError.number, 3);
END;
END LoadError;
VAR
buf: CHAR;
col: CARDINAL;
curr: l2w;
CO: ConsoleOutDCB;
stopParms: StopDCB;
BEGIN
IF userHasAborted OR terminalError THEN
RETURN;
END;
terminalError := AllErrFatal OR (n >= 500);
scanerr := TRUE;
errorInProc := TRUE;
INC(errorCount);
IF NOT objectFileInError AND ShowProgress THEN
LoadError(n);
GetPos(source, curr.long);
IF lastLine.long > lastSym.pos.long THEN
col := lastSym.colNum + 8;
lastLine := lastSym.line;
sourceLine := lastSym.lineNum;
sourceColumn := lastSym.colNum;
ELSE
col := sourceColumn + 8 - VAL(CARDINAL, curr.long - lastSym.pos.long);
END;
WriteCard(sourceLine, 5);
WriteString(' : ');
IF firstError.position = VAL(LONGINT, 0) THEN
firstError.position := lastSym.pos.long;
Assign(errorString^, firstError.string);
END;
DisplayLastLine;
REPEAT
Write(' ');
DEC(col);
UNTIL col < 1;
WriteString('^ ');
WriteString(errorString^);
WriteLn;
BusyRead(buf);
IF (buf <> nul) OR PauseOnError THEN
CO.pCount := 1;
CO.ch := scEnableMouse;
ConsoleOut(CO);
CO.ch := scSetInverse;
ConsoleOut(CO);
CO.ch := 'C'; (* hour glass symbol *)
ConsoleOut(CO);
CO.ch := scSetNormal;
ConsoleOut(CO);
CO.ch := scDisableMouse;;
ConsoleOut(CO);
CO.ch := bs;
ConsoleOut(CO);
REPEAT
(*
This will, cause the compiler to quit if the user hits apple-period
when the compiler is waiting for the user to "un-pause" an error
display.
*)
stopParms.pCount := 1;
Stop(stopParms);
userHasAborted := stopParms.stopFlag;
IF NOT userHasAborted THEN
BusyRead(buf);
END;
UNTIL userHasAborted OR (buf <> nul);
END;
END;
END Mark;
(*$RangeCheck- to speed up and to avoid range errors for invalid i or j *)
(*$OverflowCheck- *)
PROCEDURE Diff(i, j: CARDINAL): INTEGER;
VAR k: CARDINAL; d: INTEGER;
BEGIN
IF IdBuf[i] # IdBuf[j] THEN
RETURN VAL(INTEGER,ORD(IdBuf[i])) - VAL(INTEGER,ORD(IdBuf[j]))
END;
k := ORD(IdBuf[i])-1; INC(i); INC(j);
LOOP
IF k = 0 THEN RETURN 0
ELSIF IdBuf[i] # IdBuf[j] THEN
RETURN VAL(INTEGER,ORD(IdBuf[i])) - VAL(INTEGER,ORD(IdBuf[j]))
ELSE INC(i); INC(j); DEC(k)
END
END
END Diff;
PROCEDURE KeepId;
BEGIN
id := id1
END KeepId;
PROCEDURE String(termCh: CHAR);
BEGIN id1 := id + 1;
IF id1 > IdBufLim THEN Mark(503); id1 := 1 END;
LOOP GetCh;
IF ch = termCh THEN EXIT END;
IF ch < " " THEN Mark(45); EXIT END;
IdBuf[id1] := ch; INC(id1)
END;
GetCh;
IF id1-id <= ORD(MAX(CHAR)) THEN
IdBuf[id] := CHR(id1-id); (*length*)
ELSE
IdBuf[id] := MAX(CHAR); (*default maximum length*)
Mark(146);
END;
IF IdBuf[id] = 2C THEN
sym := number; numtyp := 6; intval := ORD(IdBuf[id+1])
ELSE sym := string;
IF IdBuf[id] = 1C THEN (*empty string*)
IdBuf[id1] := 0C; INC(id1); IdBuf[id] := 2C
END
END
END String;
PROCEDURE Identifier;
VAR k, l, m: CARDINAL; cap: BOOLEAN;
BEGIN
id1 := id + 1; cap := TRUE;
IF id1 > IdBufLim THEN Mark(503); id1 := 1 END;
REPEAT
IdBuf[id1] := ch;
cap := cap AND (ch <= "Z");
INC(id1); GetCh
UNTIL ((CAP(ch) < "A") OR ("Z" < CAP(ch))) & ((ch < "0") OR ("9" < ch));
IdBuf[id] := CHR(id1-id); (*Length*)
IF cap THEN
k := 0; l := KW;
REPEAT m := (k + l) DIV 2;
IF Diff(id, keyTab[m].ind) <= 0 THEN l := m ELSE k := m + 1 END
UNTIL k >= l;
IF (k < KW) & (Diff(id, keyTab[k].ind) = 0) THEN sym := keyTab[k].sym
ELSE sym := ident
END
ELSE sym := ident
END
END Identifier;
PROCEDURE Number;
VAR i, j, l, d, e, n: CARDINAL;
x, f: LONGREAL;
d0, d1: LONGCARD;
neg: BOOLEAN;
lastCh: CHAR;
dig: ARRAY [0..maxBuf] OF CHAR;
longval: RECORD
CASE :BOOLEAN OF
TRUE: lc: LONGCARD;
|
FALSE: li: LONGINT;
END;
END;
PROCEDURE Ten(e: CARDINAL): LONGREAL;
VAR k: CARDINAL; u: LONGREAL;
BEGIN k := 0; u := FLOATD(1);
WHILE e > 0 DO
IF ODD(e) THEN u := pow[k] * u END;
e := e DIV 2; INC(k)
END;
RETURN u
END Ten;
BEGIN sym := number; i := 0; l := 0; (* V2.6 *)
REPEAT dig[i] := ch; INC(l); (* V2.6 *)
IF i < maxBuf THEN INC(i) END; (* V2.6 *)
GetCh (* V2.6 *)
UNTIL (ch < "0") OR ("9" < ch) & (CAP(ch) < "A") OR ("Z" < CAP(ch));
IF l > maxBuf THEN Mark(46) END; (* too many digits *) (* V2.6 *)
lastCh := ch; j := 0;
WHILE (j < i) & (dig[j] = "0") DO INC(j) END;
IF ch = "." THEN GetCh;
IF ch = "." THEN
lastCh := 0C; ch := 177C (*ellipsis*)
END
END;
IF lastCh = "." THEN (*decimal point*)
x := FLOATD(0); l := 0;
WHILE j < i DO (*read integer part*)
IF l < maxDig THEN
IF dig[j] > "9" THEN Mark(40) END;
x := x * FLOATD(10) + FLOATD(ORD(dig[j]) - 60B);
INC(l)
ELSE Mark(41)
END;
INC(j)
END;
l := 0; f := FLOATD(0);
WHILE ("0" <= ch) & (ch <= "9") DO (*read fraction*)
IF l < maxDig THEN
f := f * FLOATD(10) + FLOATD(ORD(ch) - 60B);
INC(l)
END;
GetCh
END;
x := f / Ten(l) + x; e := 0; neg := FALSE; numtyp := 4;
IF (ch = "E") OR (ch = "L") THEN
IF ch = "L" THEN numtyp := 5 END;
GetCh;
IF ch = "-" THEN
neg := TRUE; GetCh
ELSIF ch = "+" THEN GetCh
END;
WHILE ("0" <= ch) & (ch <= "9") DO (*read exponent*)
d := ORD(ch) - 60B; (* V2.6 *)
IF (MaxCard - d) DIV 10 >= e THEN (* avoid cardinal ov *) (* V2.6 *)
e := e*10 + d; (* V2.6 *)
END; (* V2.6 *)
GetCh
END
END;
IF neg THEN
IF e <= maxExp THEN
x := x / Ten(e);
ELSE
x := FLOATD(0);
END;
ELSE
IF e <= maxExp THEN
f := Ten(e);
IF f = 0.0L THEN
x := 0.0L;
ELSIF ABS(MAX(LONGREAL)) / f >= x THEN
x := f*x;
ELSE
Mark(41);
END;
ELSE
Mark(41);
END;
END;
IF numtyp = 5 THEN
lrlval := x;
ELSE
IF x <= LONG(ABS(MAX(REAL))) THEN
realval := SHORT(x);
ELSE
Mark(41);
realval := FLOAT(1);
END;
END;
ELSE (*integer*)
lastCh := dig[i-1];
IF lastCh = "B" THEN DEC(i);
numtyp := 1; intval := 0;
WHILE j < i DO
d := ORD(dig[j]) - 60B;
IF (d < 10B) & ((MaxCard - d) DIV 10B >= intval) THEN (* V2.6 *)
intval := 10B * intval + d
ELSE Mark(29); intval := 0
END;
INC(j)
END
ELSIF lastCh = "H" THEN DEC(i);
IF i <= j+4 THEN
numtyp := 1; intval := 0;
WHILE j < i DO
d := ORD(dig[j]) - 60B;
IF d > 26B THEN Mark(29); d := 0
ELSIF d > 9 THEN d := d-7
END;
intval := 10H * intval + d; INC(j)
END
ELSIF i <= j+8 THEN
numtyp := 2; longval.lc := 0;
REPEAT d := ORD(dig[j]) - 60B;
IF d > 26B THEN Mark(29); d := 0
ELSIF d > 9 THEN d := d-7
END;
longval.lc := longval.lc * VAL(LONGCARD, 16) + VAL(LONGCARD, d);
INC(j);
UNTIL j = i;
dblval := longval.li;
ELSE Mark(29); numtyp := 2; dblval := 0
END
ELSIF lastCh = "L" THEN DEC(i);
numtyp := 2;
d1 := 0;
WHILE j < i DO
d0 := VAL(LONGCARD, ORD(dig[j]) - 60B);
IF (d0 < 10) AND ((MAX(LONGCARD) - d0) DIV 10 >= d1) THEN
d1 := 10 * d1 + d0;
ELSE
Mark(29);
d1 := 0;
END;
INC(j);
END;
dblval := d1;
ELSIF lastCh = "C" THEN DEC(i);
numtyp := 3; intval := 0;
WHILE j < i DO
d := ORD(dig[j]) - 60B; intval := 10B * intval + d;
IF (d >= 10B) OR (intval >= 400B) THEN
Mark(29); intval := 0
END;
INC(j)
END
ELSE (*decimal?*)
numtyp := 1;
intval := 0;
d1 := 0;
WHILE j < i DO
d0 := VAL(LONGCARD, ORD(dig[j]) - 60B);
IF (d0 < 10) AND ((MAX(LONGCARD) - d0) DIV 10 >= d1) THEN
d1 := 10 * d1 + d0;
ELSE
Mark(29);
d1 := 0;
END;
INC(j);
END;
IF d1 > VAL(LONGCARD, MAX(CARDINAL)) THEN
numtyp := 2;
dblval := d1;
ELSE
intval := d1;
END;
END
END
END Number;
(* $RangeCheck+*)
(* $OverflowCheck+ *)
PROCEDURE GetSym;
PROCEDURE TestOption;
VAR
k, l, m: CARDINAL;
theDirective: aDirective;
intersection: aDirectiveSet;
name: aSymbol;
BEGIN
id1 := id + 1;
IF id1 > IdBufLim THEN
Mark(503);
id1 := 1;
END;
REPEAT
IdBuf[id1] := ch;
INC(id1);
GetCh;
UNTIL (CAP(ch) < "A") OR ("Z" < CAP(ch));
IdBuf[id] := CHR(id1-id); (*Length*)
k := 0;
l := maxDirective;
REPEAT
m := (k + l) DIV 2;
IF Diff(id, dirTab[m].name) <= 0 THEN
l := m;
ELSE
k := m + 1;
END;
UNTIL k >= l;
IF (k < maxDirective) AND (Diff(id, dirTab[k].name) = 0) THEN
theDirective := dirTab[k].directive;
CASE theDirective OF
RangeCheck, OverflowCheck, NILCheck, StackCheck, DataBank:
IF (theDirective IN aDirectiveSet{StackCheck, DataBank}) AND
(curLev > 0) THEN
(*
Some directives are not valid within the scope of a procedure.
*)
Mark(511);
END;
(*
Syntax is:
Directive"+"|"-"
*)
IF ch = "+" THEN
INCL(Directives, dirTab[k].directive);
CASE dirTab[k].directive OF
RangeCheck:
rngchk := TRUE;
|
OverflowCheck:
ovflchk := TRUE;
|
StackCheck:
stackchk := TRUE;
|
NILCheck:
nilchk := TRUE;
|
DataBank:
databank := TRUE;
ELSE
END;
ELSIF ch = "-" THEN
EXCL(Directives, dirTab[k].directive);
CASE dirTab[k].directive OF
RangeCheck:
rngchk := FALSE;
|
OverflowCheck:
ovflchk := FALSE;
|
StackCheck:
stackchk := FALSE;
|
NILCheck:
nilchk := FALSE;
|
DataBank:
databank := FALSE;
ELSE
END;
ELSE
Mark(304);
END;
|
Segment, Dynamic:
IF curLev > 0 THEN
Mark(511);
END;
(*
Syntax is:
Directive "name"
where "name" is the segment name to use
*)
GetSym;
IF (sym = string) OR (sym = ident) THEN
IdToSymbol(id, segmentName);
INCL(Directives, dirTab[k].directive);
(*
Segment and Dynamic are mutually exclusive
*)
CASE dirTab[k].directive OF
Segment:
EXCL(Directives, Dynamic);
|
Dynamic:
EXCL(Directives, Segment);
ELSE
END;
ELSE
Mark(304);
END;
|
CDA:
(*
Syntax is:
CDA "name" "shutdown"
where "name" is the name of the CDA placed in the header
and "shutdown" is the (case sensitive) name of the shutdown
procedure.
*)
IF NOT moduleDeclared THEN
intersection := Directives * aDirectiveSet{NDA, RTL, CDEV, INIT};
IF intersection = aDirectiveSet{} THEN
GetSym;
IF (sym = string) OR
(sym = ident) THEN
CDAName := id;
KeepId;
GetSym;
IF (sym = string) OR
(sym = ident) THEN
CDAShutdown := id;
KeepId;
INCL(Directives, dirTab[k].directive);
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(509);
END;
ELSE
Mark(510);
END;
|
NDA:
(*
Syntax is:
NDA "open" "close" "action" period eventmask "menuline"
where "open" is the name of the open procedure
"close" is the name of the close procedure
"action" is the name of the action procedure
period is a number (0H..FFFFH) representing the action
frequency.
eventmask is a longcard number (0H..FFFFFFFFH) taking
the same format as an event manager eventmask.
"menuline" is a string containing the menu item for the
apple menu.
*)
IF NOT moduleDeclared THEN
intersection := Directives * aDirectiveSet{CDA, RTL, CDEV, INIT};
IF intersection = aDirectiveSet{} THEN
GetSym;
IF (sym = string) OR
(sym = ident) THEN
NDAOpen := id;
KeepId;
GetSym;
IF (sym = string) OR
(sym = ident) THEN
NDAClose := id;
KeepId;
GetSym;
IF (sym = string) OR
(sym = ident) THEN
NDAAction := id;
KeepId;
GetSym;
IF (sym = number) OR
(numtyp = 1) THEN
NDAPeriod := intval;
GetSym;
IF (sym = number) AND
(numtyp = 1) THEN
NDAMask := intval;
GetSym;
IF (sym = string) OR
(sym = ident) THEN
NDAMenuline := id;
KeepId;
INCL(Directives, dirTab[k].directive);
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(304);
END;
ELSE
Mark(509);
END;
ELSE
Mark(510);
END;
|
RTL:
IF NOT moduleDeclared THEN
intersection := Directives * aDirectiveSet{CDA, NDA, CDEV, INIT};
IF intersection = aDirectiveSet{} THEN
INCL(Directives, dirTab[k].directive);
ELSE
Mark(509);
END;
ELSE
Mark(510);
END;
|
CDEV:
(*
Syntax is:
CDEV "entry"
where "entry" is the name of the procedure called to handle
each cdev message.
*)
IF NOT moduleDeclared THEN
intersection := Directives * aDirectiveSet{CDA, NDA, RTL, INIT};
IF intersection = aDirectiveSet{} THEN
GetSym;
IF (sym = string) OR
(sym = ident) THEN
CDEVName := id;
KeepId;
INCL(Directives, dirTab[k].directive);
ELSE
Mark(304);
END;
ELSE
Mark(509);
END;
ELSE
Mark(510);
END;
|
INIT:
IF NOT moduleDeclared THEN
intersection := Directives * aDirectiveSet{CDA, NDA, RTL, CDEV};
IF intersection = aDirectiveSet{} THEN
INCL(Directives, dirTab[k].directive);
ELSE
Mark(509);
END;
ELSE
Mark(510);
END;
|
Pascal:
IF curLev > 0 THEN
Mark(511);
END;
(*
Syntax is:
Pascal"+"|"-"
*)
IF ch = "+" THEN
INCL(Directives, dirTab[k].directive);
ELSIF ch = "-" THEN
EXCL(Directives, dirTab[k].directive);
ELSE
Mark(304);
END;
|
NoImp:
IF NOT moduleDeclared THEN
isint := TRUE;
ELSE
Mark(510);
END;
|
StackSize:
IF NOT moduleDeclared THEN
GetSym;
IF (sym = number) OR
(numtyp = 1) THEN
INCL(Directives, dirTab[k].directive);
Stacksize := intval;
ELSE
Mark(304);
END;
ELSE
Mark(510);
END;
|
Keep:
(*
Syntax is:
Keep "keepname"
where "keepname" is to be the name of the object file, less it's
extension.
If the shell does not provide a keep name, and this directive is
not present, then the compiler will not generate an object file.
*)
IF NOT moduleDeclared THEN
GetSym;
IF (sym = string) OR
(sym = ident) THEN
IF NOT KeepObject THEN
INCL(Directives, dirTab[k].directive);
KeepObject := TRUE;
IdToSymbol(id, name);
Assign(name, outFileMask);
StringToGSOSOutString(name, OutputFile);
keepStyle := kSaveObject;
END;
ELSE
Mark(304);
END;
ELSE
Mark(510);
END;
|
ChainTo:
(*
Syntax is:
Chain "filename"
where "filename" is the pathname of a file to be compiled after
the current file.
If this directive is used, the compiler places the name in the
sFile parameter of a SetLInfo call before terminating, allowing
the shell to automatically invoke the appropriate compiler.
*)
IF NOT moduleDeclared THEN
GetSym;
IF (sym = string) OR
(sym = ident) THEN
INCL(Directives, dirTab[k].directive);
ChainToName := id;
KeepId;
ELSE
Mark(304);
END;
ELSE
Mark(510);
END;
END;
ELSE
Mark(305) (* invalid option *)
END
END TestOption;
PROCEDURE Comment;
VAR
commentPos: l2w;
commentLastLine: l2w;
commentSym: aSymbolPos;
commentLine: CARDINAL;
commentColumn: CARDINAL;
BEGIN
commentLastLine := lastLine;
commentSym := lastSym;
commentLine := sourceLine;
commentColumn := sourceColumn;
GetPos(source, commentPos.long);