kanboard: init at 1.2.42

nixos/doc/manual/release-notes/rl-2505.section.md

@@ -18,6 +18,8 @@
 
 - [agorakit](https://github.com/agorakit/agorakit), an organization tool for citizens' collectives. Available with [services.agorakit](#opt-services.agorakit.enable).
 
+- [KanBoard](https://github.com/kanboard/kanboard), a project management tool that focuses on the Kanban methodology. Available as [services.kanboard](#opt-services.kanboard.enable).
+
 <!-- To avoid merge conflicts, consider adding your item at an arbitrary place in the list instead. -->
 
 ## Backward Incompatibilities {#sec-release-25.05-incompatibilities}

nixos/modules/module-list.nix

@@ -1466,6 +1466,7 @@
   ./services/web-apps/jirafeau.nix
   ./services/web-apps/jitsi-meet.nix
   ./services/web-apps/kasmweb/default.nix
+  ./services/web-apps/kanboard.nix
   ./services/web-apps/kavita.nix
   ./services/web-apps/keycloak.nix
   ./services/web-apps/kimai.nix

nixos/modules/services/web-apps/kanboard.nix

@@ -0,0 +1,156 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.services.kanboard;
+
+  toStringAttrs = lib.mapAttrs (lib.const toString);
+in
+{
+  meta.maintainers = with lib.maintainers; [ yzx9 ];
+
+  options.services.kanboard = {
+    enable = lib.mkEnableOption "Kanboard";
+
+    package = lib.mkPackageOption pkgs "kanboard" { };
+
+    dataDir = lib.mkOption {
+      type = lib.types.str;
+      default = "/var/lib/kanboard";
+      description = "Default data folder for Kanboard.";
+      example = "/mnt/kanboard";
+    };
+
+    user = lib.mkOption {
+      type = lib.types.str;
+      default = "kanboard";
+      description = "User under which Kanboard runs.";
+    };
+
+    settings = lib.mkOption {
+      type =
+        with lib.types;
+        attrsOf (oneOf [
+          str
+          int
+          bool
+        ]);
+
+      default = { };
+
+      description = ''
+        Customize the default settings, refer to <https://github.com/kanboard/kanboard/blob/main/config.default.php>
+        for details on supported values.
+      '';
+    };
+
+    # Nginx
+    domain = lib.mkOption {
+      type = lib.types.str;
+      description = "FQDN for the Kanboard instance.";
+      example = "kanboard.example.org";
+    };
+    nginx = lib.mkOption {
+      type = lib.types.nullOr (
+        lib.types.submodule (import ../web-servers/nginx/vhost-options.nix { inherit config lib; })
+      );
+      default = null;
+      description = ''
+        With this option, you can customize an NGINX virtual host which already
+        has sensible defaults for Kanboard. Set to `{ }` if you do not need any
+        customization for the virtual host. If enabled, then by default, the
+        {option}`serverName` is `''${domain}`. If this is set to null (the
+        default), no NGINX virtual host will be configured.
+      '';
+      example = lib.literalExpression ''
+        {
+          enableACME = true;
+          forceHttps = true;
+        }
+      '';
+    };
+
+    phpfpm.settings = lib.mkOption {
+      type =
+        with lib.types;
+        attrsOf (oneOf [
+          int
+          str
+          bool
+        ]);
+      default = {
+        "pm" = "dynamic";
+        "php_admin_value[error_log]" = "stderr";
+        "php_admin_flag[log_errors]" = true;
+        "listen.owner" = "nginx";
+        "catch_workers_output" = true;
+        "pm.max_children" = "32";
+        "pm.start_servers" = "2";
+        "pm.min_spare_servers" = "2";
+        "pm.max_spare_servers" = "4";
+        "pm.max_requests" = "500";
+      };
+
+      description = ''
+        Options for kanboard's PHPFPM pool.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    users.users.${cfg.user} = {
+      isSystemUser = true;
+      group = "nginx";
+      home = cfg.dataDir;
+      createHome = true;
+    };
+
+    services.phpfpm.pools.kanboard = {
+      user = "kanboard";
+      group = "nginx";
+
+      inherit (cfg.phpfpm) settings;
+
+      phpEnv = lib.mkMerge [
+        { DATA_DIR = cfg.dataDir; }
+        (toStringAttrs cfg.settings)
+      ];
+    };
+
+    services.nginx = lib.mkIf (cfg.nginx != null) {
+      enable = lib.mkDefault true;
+      virtualHosts."${cfg.domain}" = lib.mkMerge [
+        {
+          root = "${cfg.package}/share/kanboard";
+          locations."/".extraConfig = ''
+            rewrite ^ /index.php;
+          '';
+          locations."~ \\.php$".extraConfig = ''
+            fastcgi_split_path_info ^(.+\.php)(/.+)$;
+            fastcgi_pass unix:${config.services.phpfpm.pools.kanboard.socket};
+            include ${config.services.nginx.package}/conf/fastcgi.conf;
+            include ${config.services.nginx.package}/conf/fastcgi_params;
+          '';
+          locations."~ \\.(js|css|ttf|woff2?|png|jpe?g|svg)$".extraConfig = ''
+            add_header Cache-Control "public, max-age=15778463";
+            add_header X-Content-Type-Options nosniff;
+            add_header X-XSS-Protection "1; mode=block";
+            add_header X-Robots-Tag none;
+            add_header X-Download-Options noopen;
+            add_header X-Permitted-Cross-Domain-Policies none;
+            add_header Referrer-Policy no-referrer;
+            access_log off;
+          '';
+          extraConfig = ''
+            try_files $uri /index.php;
+          '';
+        }
+        cfg.nginx
+      ];
+    };
+  };
+}

pkgs/by-name/ka/kanboard/package.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+stdenvNoCC.mkDerivation (attrs: {
+  pname = "kanboard";
+  version = "1.2.42";
+
+  src = fetchFromGitHub {
+    owner = "kanboard";
+    repo = "kanboard";
+    rev = "refs/tags/v${attrs.version}";
+    hash = "sha256-/Unxl9Vh9pEWjO89sSviGGPFzUwxdb1mbOfpTFTyRL0=";
+  };
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p $out/share/kanboard
+    cp -rv . $out/share/kanboard
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Kanban project management software";
+    homepage = "https://kanboard.org";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ yzx9 ];
+  };
+})