scipoptsuite: init at 9.2.0

maintainers/maintainer-list.nix

@@ -7497,6 +7497,12 @@
     githubId = 11705326;
     name = "Max Kochurov";
   };
+  fettgoenner = {
+    email = "[email protected]";
+    github = "fettgoenner";
+    githubId = 92429150;
+    name = "Paul Meinhold";
+  };
   ffinkdevs = {
     email = "[email protected]";
     github = "ffinkdevs";

pkgs/by-name/sc/scipopt-gcg/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  pkgs,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  scipopt-scip,
+  cliquer,
+  gsl,
+  gmp,
+  bliss,
+  nauty,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "scipopt-gcg";
+  version = "370";
+
+  src = fetchFromGitHub {
+    owner = "scipopt";
+    repo = "gcg";
+    tag = "v${version}";
+    hash = "sha256-s7VmBWwDSGa7fAoydg54OHvulFWda8E48nEVsdCdQt8=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    scipopt-scip
+    cliquer
+    gsl
+    gmp
+    bliss
+    nauty
+  ];
+
+  # Fixing the error
+  #   > CMake Error at CMakeLists.txt:236 (find_package):
+  #   >   By not providing "FindNAUTY.cmake" in CMAKE_MODULE_PATH this project has
+  #   >   asked CMake to find a package configuration file provided by "NAUTY", but
+  #   >   CMake did not find one.
+  # with this weird workaround of setting SCIPOptSuite_SOURCE_DIR to include the scipopt-scip source
+  # files via symlinks, so the specific nauty files are found:
+  preConfigure = ''
+    mkdir -pv $out/scip
+    ln -sv ${scipopt-scip.src}/src/ $out/scip/src
+    cmakeFlagsArray+=(
+      "-DSCIPOptSuite_SOURCE_DIR=$out"
+    )
+  '';
+
+  meta = {
+    maintainers = with lib.maintainers; [ fettgoenner ];
+    description = "Branch-and-Price & Column Generation for Everyone";
+    license = lib.licenses.lgpl3;
+    homepage = "https://gcg.zib.de";
+  };
+}

pkgs/by-name/sc/scipopt-papilo/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  cmake,
+  fetchFromGitHub,
+  boost,
+  blas,
+  gmp,
+  tbb_2021_11,
+  gfortran,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "scipopt-papilo";
+  version = "2.4.0";
+
+  src = fetchFromGitHub {
+    owner = "scipopt";
+    repo = "papilo";
+    tag = "v${version}";
+    hash = "sha256-WMw9v57nuP6MHj9Ft4l5FxdIF5VUWCRm/909tbz7VD4=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    blas
+    gmp
+    gfortran
+    boost
+    tbb_2021_11
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "GMP" true)
+    (lib.cmakeBool "QUADMATH" true)
+    (lib.cmakeBool "TBB" true)
+    (lib.cmakeBool "TBB_DOWNLOAD" false)
+    (lib.cmakeBool "SOPLEX" false)
+  ];
+
+  meta = {
+    maintainers = with lib.maintainers; [ fettgoenner ];
+    description = "Parallel Presolve for Integer and Linear Optimization";
+    license = lib.licenses.lgpl3;
+    homepage = "https://github.com/scipopt/papilo";
+    mainProgram = "papilo";
+  };
+}

pkgs/by-name/sc/scipopt-scip/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  fetchFromGitHub,
+  cmake,
+  zlib,
+  readline,
+  gmp,
+  scipopt-soplex,
+  scipopt-papilo,
+  scipopt-zimpl,
+  ipopt,
+  tbb_2021_11,
+  boost,
+  gfortran,
+  criterion,
+  mpfr,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "scipopt-scip";
+  version = "9.2.0";
+
+  src = fetchFromGitHub {
+    owner = "scipopt";
+    repo = "scip";
+    tag = "v${lib.replaceStrings [ "." ] [ "" ] version}";
+    hash = "sha256-F9PBnPuGh+vDYuBL9R0pWg0PUiDrrKT4YdOH1K22dRk=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    scipopt-soplex
+    scipopt-papilo
+    scipopt-zimpl
+    ipopt
+    gmp
+    readline
+    zlib
+    tbb_2021_11
+    boost
+    gfortran
+    criterion
+    mpfr # if not included, throws fatal error: mpfr.h not found
+  ];
+
+  cmakeFlags = [ ];
+
+  meta = {
+    maintainers = with lib.maintainers; [ fettgoenner ];
+    description = "Solving Constraint Integer Programs";
+    license = lib.licenses.asl20;
+    homepage = "https://github.com/scipopt/scip";
+    mainProgram = "scip";
+  };
+}

pkgs/by-name/so/soplex/package.nix → pkgs/by-name/sc/scipopt-soplex/package.nix

@@ -2,11 +2,15 @@
   lib,
   stdenv,
   cmake,
+  gmp,
+  mpfr,
+  zlib,
+  boost,
   fetchFromGitHub,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
-  pname = "soplex";
+  pname = "scipopt-soplex";
   version = "712";
 
   src = fetchFromGitHub {
@@ -18,12 +22,20 @@ stdenv.mkDerivation (finalAttrs: {
 
   nativeBuildInputs = [ cmake ];
 
+  buildInputs = [
+    gmp
+    mpfr
+    zlib
+    boost
+    mpfr
+  ];
+
   strictDeps = true;
 
   doCheck = true;
 
   meta = {
-    homepage = "https://scipopt.org";
+    homepage = "https://soplex.zib.de/";
     description = "Sequential object-oriented simPlex";
     license = with lib.licenses; [ asl20 ];
     mainProgram = "soplex";

pkgs/by-name/sc/scipopt-ug/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  cmake,
+  scipopt-scip,
+  zlib,
+  mpi,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "scipopt-ug";
+  version = "1.0.0-beta6";
+
+  # Take the SCIPOptSuite source since no other source exists publicly.
+  src = fetchzip {
+    url = "https://github.com/scipopt/scip/releases/download/v920/scipoptsuite-9.2.0.tgz";
+    sha256 = "SaIo/U9cconmGRxEPV5M7IO6+L9wGCaXqxifefUzFk4=";
+  };
+
+  sourceRoot = "${src.name}/ug";
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    scipopt-scip
+    mpi
+    zlib
+  ];
+
+  meta = {
+    maintainers = with lib.maintainers; [ fettgoenner ];
+    description = "Ubiquity Generator framework to parallelize branch-and-bound based solvers";
+    license = lib.licenses.lgpl3;
+    homepage = "https://ug.zib.de";
+  };
+}

pkgs/by-name/sc/scipopt-zimpl/package.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  bison,
+  flex,
+  gmp,
+  zlib,
+}:
+
+stdenv.mkDerivation {
+  pname = "scipopt-zimpl";
+  version = "362";
+
+  src = fetchFromGitHub {
+    owner = "scipopt";
+    repo = "zimpl";
+    rev = "v362";
+    sha256 = "juqAwzqBArsFXmz7L7RQaE78EhQdP5P51wQFlCoo7/o=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    bison
+    flex
+  ];
+
+  buildInputs = [
+    gmp
+    zlib
+  ];
+
+  meta = {
+    maintainers = with lib.maintainers; [ fettgoenner ];
+    description = "Zuse Institut Mathematical Programming Language";
+    longDescription = ''
+      ZIMPL is a little language to translate the mathematical model of a
+      problem into a linear or (mixed-)integer mathematical program
+      expressed in .lp or .mps file format which can be read by a LP or MIP
+      solver.
+
+      If you use Zimpl for research and publish results, the best way
+      to refer to Zimpl is to cite my Ph.d. thesis:
+
+      @PHDTHESIS{Koch2004,
+         author      = "Thorsten Koch",
+         title       = "Rapid Mathematical Programming",
+         year        = "2004",
+         school      = "Technische {Universit\"at} Berlin",
+         url         = "http://www.zib.de/Publications/abstracts/ZR-04-58/",
+         note        = "ZIB-Report 04-58",
+      }
+    '';
+    license = lib.licenses.lgpl3;
+    homepage = "https://zimpl.zib.de";
+  };
+}